| Autor |
Beitrag |
    
Charles (Charles)
| | Veröffentlicht am Donnerstag, den 01. März, 2001 - 15:12: | 
|
Mir will die Polynomdivision bei folgender Gleichung nicht gelingen:
0.5x^3-2x^2-2,5x-1=0
Vielen Dank schon mal! |
Manuela
| | Veröffentlicht am Donnerstag, den 01. März, 2001 - 15:30: |
|
Du hast dich beim Zusammenrechnen vertan. (siehe meinen 2.Eintrag) |
magnum
| | Veröffentlicht am Freitag, den 02. März, 2001 - 02:22: |
|
eine nullstelle ist: 5.0651
den rest kannst du hiermit selbst ausrechnen.
viel spass!
10 CLEAR :PRINT "Polynomdivision"
20 INPUT "Grad des zu div.Poly=";N1
30 DIM A(N1),E(1,N1)
40 FOR A=0TO N1:PRINT "a";A;
50 INPUT A(A):E(1,A)=A(A):NEXT A
60 INPUT "Grad des div.Poly=";N2
70 N3=N1-N2:IF N3<0THEN END
80 DIM B(N2),C(N3),D(N2-1)
90 FOR A=0 TO N2:PRINT "b";A;
100 INPUT B(A):NEXT A
110 PRINT "(";:GOTO 240
120 REM Anzeige des Polynoms
130 FOR B=A TO 0 STEP -1:IF E(0,B)=0THEN 230
140 IF E(0,B)<0THEN 160 ELSE 150
150 IF B=A THEN 160 ELSE PRINT "+";
160 IF ABS (E(0,B))=1 AND B=0 THEN 170 ELSE 180
170 PRINT E(0,B);:GOTO 230
180 IF ABS (E(0,B))=1 THEN 190ELSE PRINT E(0,B);
190 IF E(0,B)=-1 THEN PRINT "-";
200 IF B=0THEN 230
210 PRINT "x";:IF B=1THEN 230
220 PRINT "^";B;
230 NEXT B:RETURN
240 A=N1:FOR B=0TO A:E(0,B)=A(B):NEXT B
250 GOSUB 120:PRINT ")/(";:A=N2
260 FOR B=0TO A:E(0,B)=B(B):NEXT B
270 GOSUB 120:PRINT ")="
280 C(N3)=A(N1)/B(N2):IF N3=0THEN 360
290 FOR A=N3-1TO 0 STEP -1
300 B=N1-N3+A
310 FOR C=B TO B-N2+1 STEP -1
320 D=N2+C-B-1
330 A(C)=A(C)-C(A+1)*B(D)
340 NEXT C
350 C(A)=A(B)/B(N2):NEXT A
360 FOR A=0TO N3:E(0,A)=C(A):NEXT A
370 A=N3:GOSUB 120:ZR=0:FOR A=0TO N2-1
380 D(A)=A(A)-B(A)*C(0):E(0,A)=D(A)
390 IF ABS (D(A))>0THEN ZR=ZR+1
400 NEXT A:IF ZR=0THEN END ELSE PRINT "+(";
410 FOR B=0TO N2-1:E(0,B)=D(B):NEXT B
420 A=N2-1:GOSUB 120:PRINT ")/(";
430 FOR B=0TO N2:E(0,B)=B(B):NEXT B
440 A=N2:GOSUB 120:PRINT ")" |
|
